dotNETportal.cz

Kód funguje bez problémů. Chyba bude v tom, že máte nejspíš deklarováno NovyUzivatel na nesprávném místě (aby to fungovalo správně, musí se deklarovat jako Private na úrovni třídy a životnost končí v momentě zaniknutí této třídy).

Při deklarování událostí je doporučeno používat události založené na generickém delegátu EventHandler(Of TEventArgs). Parametr sender je zdroj, ze kterého událost pochází, ve většině případů tam můžete dosadit Me. Parametr e jsou parametry události, což je libovolná třída odvozená od třídy EventArgs.

Následující příklad ukazuje praktické použití.

Module Module1
  'Deklarativní definice třídy s událostí
  Private WithEvents _mainWorker As New Worker
  Sub Main()
    'Spustit činnost
    _mainWorker.DoWork()
    Console.ReadKey()
  End Sub
  'Obslužná metoda události WorkCompleted
  Private Sub _mainWorker_WorkCompleted(ByVal sender As Object, ByVal e As WorkCompletedEventArgs) Handles _mainWorker.WorkCompleted
    'Provést pouze pokud zdroj události je typu Worker
    Dim worker = TryCast(sender, Worker)
    If worker IsNot Nothing Then
      Console.WriteLine(String.Format("Výsledek z {0} je {1}.", worker.Id, e.Result))
    End If
  End Sub
End Module

Public Class Worker
  'Identifikátor třídy
  Private _id As String
  'Definice události pomocí generického delegátu
  Public Event WorkCompleted As EventHandler(Of WorkCompletedEventArgs)
  Public Sub New()
    'Vytvoření unikátního identifikátoru třídy
    _id = Guid.NewGuid().ToString().ToUpper()
  End Sub
  Public Sub DoWork()
    'Simulace činnosti
    Threading.Thread.Sleep(1000)
    Dim randomizer As New Random
    Dim e As New WorkCompletedEventArgs(randomizer.Next())
    'Vyvolání události
    RaiseEvent WorkCompleted(Me, e)
  End Sub
  Public ReadOnly Property Id() As String
    Get
      Return _id
    End Get
  End Property
End Class

'Parametry události dokončení činnosti (WorkCompleted)
Public Class WorkCompletedEventArgs
  Inherits EventArgs
  Private _result As Integer
  Public Sub New(ByVal result As Integer)
    _result = result
  End Sub
  'Výsledek činnosti
  Public ReadOnly Property Result() As Integer
    Get
      Return _result
    End Get
  End Property
End Class 

Pokud máte v době vytváření instance třídy již deklarativně přiřazenou obslužnou metodu, potom to bude fungovat.